etayn

damage.zsc (5153B)

---

 extend class DevilbunnyPlayer
 {	
 	//	0 = UNARMORED
 	//	1 = BRIGANDINE (backpack replacement, 50% damage reduction)
 	//	2 = MARISKULL	(radsuit replacement)
 	//	wish zscript supported enums
 	int hasArmorType;
 	
 	//the target that the player's summons will attack. Decided by
 	//1. last monster that damaged the player
 	//2. closest monster (to the player) targeting the player 
 	actor summonTarget;
 	int targetRange;
 	int targetPriority;
 
 	void PissOffSummons(Actor target, int priority)
 	{
 		if (priority > targetPriority)
 		{
 			summonTarget = target;
 			targetPriority = priority + 40;
 		}
 	}
 
 	void HandleSTarget()
 	{	
 		//reset this every frame so the
 		//eventhandler can figure out which
 		//alerted monster is closest to the player
 		targetRange = 4000;
 
 		//target's priority diminishes over time
 		//so summons will switch targets
 		if (targetPriority > 0)
 		{
 			targetPriority -= 1;
 		}
 		else
 		{
 			//forget about targets that don't have LOS with the player
 			//(eventually)
 			if (!CheckSight(summonTarget))
 			{
 				summonTarget = null;
 				return;
 			}
 		}
 
 		//if no summonTarget, set priority to 0 so that'll always
 		//change if another valid target is found
 		if(!summonTarget)
 		{
 			targetPriority = 0;
 			return;
 		}
 
 		//check for things that are targeted
 		//by summons but shouldn't be
 		if (
 				/*dead monsters*/
 				summonTarget.InStateSequence(
 					summonTarget.CurState, 
 					summonTarget.ResolveState("Death")) 
 				|| summonTarget.InStateSequence(
 					summonTarget.CurState, 
 					summonTarget.ResolveState("XDeath"))
 				/*the summoner*/
 				|| (summonTarget == self)
 				/*Another summon (or itself)*/
 				|| (summonTarget is "SummonBase")
 			)
 		{
 			summonTarget = null;
 			targetPriority = 0;
 		}
 	}
 	
 	override int DamageMobj(Actor inflictor, Actor source, int damage, Name mod, int flags, double angle)
 	{
 		if (flags & DMG_FORCED) //kill instantly if A_Die() is called
 		{
 			damage = 1;
 			return Super.DamageMobj(inflictor, source, damage, mod, flags, angle);
 		}
 		//this mod doesn't use doom-style armor. Just in case the player ends up with it, somehow...
 		flags = flags | DMG_NO_ARMOR;
 		
 		int sreduce; //amount to reduce the damage due to spirit
 	
 		sreduce = damage / 3;
 		
 		if (!(flags & DMG_NO_FACTOR))
 		{
 			if (mod == "PlayerDamage")
 			{
 				damage = 0;
 				sreduce = 0;
 			}
 			if (self.hasArmorType == 1) //wearing half damage armor
 			{
 				damage = damage / 2;
 				if (mod == "Melee")
 				{
 					damage = 0;
 					sreduce = 0;
 				}
 			}
 			else if (self.hasArmorType == 2) //wearing radsuit replacement
 			{
 				if (mod == "Drowning" || mod == "Slime" || mod == "Poison" || mod == "Ice" ) 
 				{
 					damage = 0;
 				}
 				
 				if (mod == "Fire") 
 				{
 					damage /= 2;
 				}
 				
 				sreduce = 0;
 			}
 		}
 		
 		vector3 offs;
 		offs.z = 30;
 		if (damage >= 90)
 		{
 			spawn("BigFeatherBurst", pos + offs, NO_REPLACE);
 		}
 		else if (damage >= 40)
 		{
 			spawn("FeatherBurst", pos + offs, NO_REPLACE);
 		}
 		else if (damage >= 5)
 		{
 			spawn("MaybeFeather", pos + offs, NO_REPLACE);
 		}
 		
 		if (damage && (self.hitpoints > 0))
 		{
 			if (self.hitpoints - damage <= 0)
 			{
 				A_StartSound("bun/dying", CHAN_BODY);
 			}
 			else
 			{
 				A_StartSound("bun/ouch", CHAN_BODY);
 			}
 		}
 		
 		if (sreduce > self.spirit)
 		{
 			sreduce -= self.spirit;
 			self.spirit = 0;
 		}
 		
 		damage -= sreduce;
 		self.LoseSpirit(sreduce);
 		
 		self.LoseHealth(damage);
 		damage = 0;
 
 		if (source && mod != "PlayerDamage")
 		{
 			self.PissOffSummons(source, 300);
 		}
 		
 		return Super.DamageMobj(inflictor, source, damage, mod, flags, angle);
 	}	
 
 	void updateParryShield()
 	{
 		if (parryShield)
 		{
 			parryShield.SetOrigin(Vec3Angle(32, angle, 32), false);
 		
 			if (player.readyweapon)
 			{
 				let curweapon = DevilbunnyWeapon(player.readyweapon);
 				
 				if (curweapon.parries == TRUE)
 				{
 					parryShield.bShootable = true;
 				}
 				else
 				{
 					parryShield.bShootable = false;
 				}
 				
 				let spain = parryShield.ResolveState("Pain");
 				let scur = parryShield.CurState;
 				let parrystate = curweapon.FindState("Parry");
 				
 				
 				if(spain && scur && parrystate)
 				{
 					if (parryShield.InStateSequence(scur, spain))
 					{
 						if (curweapon.parryAnimReady)
 						{
 							player.setpsprite(PSP_WEAPON,parrystate);
 						}
 					}
 				}
 			}
 		}
 		else
 		{
 	//		A_Log("Created New ParryShield");
 			self.parryShield = spawn("ParryAct", pos);
 		}
 	}
 		
 	void GainSpirit(int amount)
 	{
 		spirit += amount;
 		targspirit += amount;
 		if (targspirit > maxspirit)
 		{
 			targspirit = maxspirit;
 			spirit = maxspirit;
 		}
 	}
 	
 	bool SpendSpirit(int amount)
 	{
 		if (hasArmorType == 2) { amount /= 2; }
 		if (spirit >= amount)
 		{
 			LoseSpirit(amount); //actually sets targspirit
 			spirit -= amount;
 			return true;
 		}
 		return false;
 	}
 	
 	void LoseSpirit(int amount)
 	{
 		targspirit -= amount;
 		if (targspirit < 0) 
 		{
 			targspirit = 0;
 		}
 	}
 	
 	void GainHealth(int amount)
 	{
 		hitpoints += amount;
 		if (hitpoints > maxhits)
 		{
 			hitpoints = maxhits;
 		}
 	}
 	
 	void LoseHealth(int amount)
 	{
 		hitpoints -= amount;
 		if (hitpoints < 0)
 		{
 			hitpoints = 0;
 		}
 	}
 }